Phanix's Blog:如何從 asp 中透過 gmail smtp 發信 / How to send mail in asp via gmail smtp

August 30,2005

如何從 asp 中透過 gmail smtp 發信 / How to send mail in asp via gmail smtp

最近因為有需要從 asp 中透過 gmail smtp 發信；
不幸的是在網路上似乎只能找到 for php, jsp, .net 的 sample code，受不了乾脆來寫一個 =.=

'Create CDO.Message object instance
Set myMail = CreateObject("CDO.Message")

'============================================================
' 使用外部 SMTP
'============================================================
'設定是否使用外部 SMTP
myMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 '1 代表使用 local smtp, 2 為外部 smtp

'SMTP Server domain name
myMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com"

'Server port, gmail use ssl smtp authentication, port number is 465
myMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465
'Authentication method, ssl or not, Username and password for the SMTP Server
myMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 'cdoBasic 基本驗證
myMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = true
myMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "username"
myMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "password"

myMail.Configuration.Fields.Update
'============================================================
' End of 使用外部 SMTP
'============================================================

myMail.Subject = strSubject
myMail.From = strEmailFrom
myMail.To = strEmailTo
myMail.TextBody = strBody
myMail.Send

set myMail=nothing

Posted by phanix at 樂多Roodo! │16:47 │回應(3) │引用(0) │電腦網路

樂多分類：網路/3C 共同主題：程式設計工具：加入樂多書籤│編輯本文